Instalasi • Ikhtisar • Skrip contoh • Membaca atau menulis gambar • Memanipulasi gambar • Mengatur atribut gambar • Mendapatkan atribut gambar • Membandingkan gambar dengan rekonstruksinya • Membuat montase gambar • Bekerja dengan blob • Akses langsung ke piksel gambar • Metode lain-lain • Menangani exception• Konstanta

PerlMagick adalah antarmuka Perl berorientasi objek untuk ImageMagick. Gunakan modul ini untuk membaca, memanipulasi, atau menulis gambar atau urutan gambar dari dalam skrip Perl. Ini membuatnya sangat cocok untuk skrip Web CGI. Anda harus memiliki ImageMagick 6.5.5 atau yang lebih baru dan Perl versi 5.005_02 atau yang lebih baru terinstal di sistem Anda agar PerlMagick dapat dibangun dengan benar.

Ada sejumlah skrip berguna yang tersedia untuk menunjukkan nilai PerlMagick. Anda dapat melakukan manipulasi dan konversi gambar berbasis Web dengan MagickStudio, atau menggunakan L-systems untuk membuat gambar tumbuhan menggunakan konstruksi matematis, dan terakhir menelusuri koleksi gambar thumbnail serta memilih gambar yang ingin dilihat dengan WebMagick Image Navigator.

Anda dapat mencoba PerlMagick dari browser Web Anda di ImageMagick Studio. Atau, Anda dapat melihat contoh beberapa fungsi PerlMagick pilihan.

Instalasi

UNIX

Apakah PerlMagick tersedia dari repositori RPM sistem Anda? Misalnya, pada sistem CentOS kami, kami menginstal PerlMagick sebagai berikut:

yum install ImageMagick-perl

Jika tidak, Anda harus menginstal PerlMagick dari distribusi sumber ImageMagick. Unduh rilis sumber terbaru.

Ekstrak distribusi tersebut dengan perintah berikut:

tar xvzf ImageMagick.tar.gz

Selanjutnya, konfigurasikan dan kompilasi ImageMagick:

cd ImageMagick-7.1.2-25
./configure -with-perl
make

Jika ImageMagick / PerlMagick berhasil dikonfigurasi dan dikompilasi tanpa keluhan, Anda siap menginstalnya pada sistem Anda. Hak akses administrator diperlukan untuk instalasi. Untuk menginstal, ketik

sudo make install

Anda mungkin perlu mengonfigurasi binding run-time dari dynamic linker:

sudo ldconfig /usr/local/lib

Terakhir, untuk memverifikasi bahwa instalasi PerlMagick berjalan dengan benar, ketik

perl -MImage::Magick -le 'print Image::Magick->QuantumDepth'

Selamat, Anda sekarang memiliki distribusi ImageMagick yang berfungsi dan siap menggunakan PerlMagick untuk mengonversi, menyusun, atau mengedit gambar Anda.

Windows XP / Windows 2000

ImageMagick harus sudah terinstal pada sistem Anda. Selain itu, distribusi sumber ImageMagick untuk Windows 2000 diperlukan. Anda juga harus memiliki nmake dari lingkungan pengembangan Visual C++ atau J++. Salin \bin\IMagick.dll dan \bin\X11.dll ke direktori dalam dynamic load path Anda, seperti c:\perl\site\5.00502.

Selanjutnya, ketik

cd PerlMagick
perl Makefile.nt
nmake
nmake install

Menjalankan Uji Regresi

Untuk memverifikasi instalasi yang benar, ketik

make test

Gunakan nmake test pada Windows. Ada beberapa skrip demonstrasi yang tersedia untuk menguji banyak fungsi yang dapat dilakukan PerlMagick. Ketik

Gunakan utilitas prove untuk menjalankan pengujian dari direktori build:

prove --blib blib -I `pwd` -bv ./t/read.t



cd demo
make

Sekarang Anda siap menggunakan metode PerlMagick dari dalam skrip Perl Anda.

Ikhtisar

Skrip mana pun yang ingin menggunakan metode PerlMagick harus terlebih dahulu mendefinisikan metode-metode tersebut dalam namespace-nya dan membuat instance objek gambar. Lakukan ini dengan:

use Image::Magick;

$image = Image::Magick->new;

PerlMagick bersifat quantum aware. Anda dapat meminta kedalaman quantum tertentu saat membuat instance objek gambar:

use Image::Magick::Q16;

$image = Image::Magick::Q16->new;

Metode new() menerima parameter yang sama dengan SetAttribute. Misalnya,

$image = Image::Magick->new(size=>'384x256');

Selanjutnya Anda akan ingin membaca gambar atau urutan gambar, memanipulasinya, lalu menampilkan atau menulisnya. Metode input dan output PerlMagick didefinisikan dalam Membaca atau menulis gambar. Lihat Mengatur atribut gambar untuk metode yang memengaruhi cara gambar dibaca atau ditulis. Lihat Memanipulasi gambar untuk daftar metode untuk mentransformasi gambar. Mendapatkan atribut gambar menjelaskan cara mengambil atribut suatu gambar. Lihat Membuat montase gambar untuk detail tentang menyusun gambar Anda sebagai thumbnail pada latar belakang. Terakhir, beberapa metode tidak cocok secara rapi ke kategori mana pun yang baru disebutkan. Lihat Metode lain-lain untuk daftar metode tersebut.

Setelah selesai menggunakan objek PerlMagick, Anda sebaiknya mempertimbangkan untuk menghancurkannya. Setiap gambar dalam urutan gambar disimpan dalam memori virtual. Ini berpotensi mencapai beberapa mebibyte memori. Setelah objek PerlMagick dihancurkan, memori dikembalikan untuk digunakan oleh metode Perl lainnya. Cara yang direkomendasikan untuk menghancurkan objek adalah dengan undef:

undef $image;

Untuk menghapus semua gambar tetapi tetap mempertahankan objek Image::Magick, gunakan

@$image = ();

dan terakhir, untuk menghapus satu gambar dari urutan multi-gambar, gunakan

undef $image->[$x];

Bagian berikutnya menggambarkan cara menggunakan berbagai metode PerlMagick untuk memanipulasi urutan gambar.

Beberapa metode PerlMagick memerlukan program eksternal seperti Ghostscript. Ini mungkin memerlukan path eksplisit dalam variabel lingkungan PATH Anda agar berfungsi dengan benar. Misalnya (pada Linux),

$ENV{PATH}' . "='/../bin:/usr/bin:/usr/local/bin';

Skrip contoh

Berikut adalah skrip contoh untuk membantu Anda memulai:

#!/usr/local/bin/perl
use Image::Magick;

my($image, $x);

$image = Image::Magick->new;
$x = $image->Read('girl.png', 'logo.png', 'rose.png');
warn "$x" if "$x";

$x = $image->Crop(geometry=>'100x100+100+100');
warn "$x" if "$x";

$x = $image->Write('x.png');
warn "$x" if "$x";

Skrip ini membaca tiga gambar, memangkasnya, dan menulis satu gambar sebagai urutan animasi GIF. Dalam banyak kasus, Anda mungkin ingin mengakses masing-masing gambar dalam suatu urutan. Contoh berikutnya menggambarkan cara melakukannya:

#!/usr/local/bin/perl
use Image::Magick;

my($image, $p, $q);

$image = new Image::Magick;
$image->Read('x1.png');
$image->Read('j*.jpg');
$image->Read('k.miff[1, 5, 3]');
$image->Contrast();
for ($x = 0; $image->[$x]; $x++)
{
  $image->[$x]->Frame('100x200') if $image->[$x]->Get('magick') eq 'GIF';
  undef $image->[$x] if $image->[$x]->Get('columns') < 100;
}
$p = $image->[1];
$p->Draw(stroke=>'red', primitive=>'rectangle', points=>20,20 100,100');
$q = $p->Montage();
undef $image;
$q->Write('x.miff');

Misalkan Anda ingin memulai dengan kanvas putih berukuran 100 kali 100 piksel dengan satu piksel merah di tengahnya. Coba

$image = Image::Magick->new;
$image->Set(size=>'100x100');
$image->ReadImage('canvas:white');
$image->Set('pixel[49,49]'=>'red');

Di sini kita mengurangi intensitas komponen merah pada (1,1) menjadi setengahnya:

@pixels = $image->GetPixel(x=>1,y=>1);
$pixels[0]*=0.5;
$image->SetPixel(x=>1,y=>1,color=>\@pixels);

Atau misalkan Anda ingin mengonversi gambar berwarna Anda menjadi grayscale:

$image->Quantize(colorspace=>'gray');

Mari kita beri anotasi pada gambar dengan font TrueType Taipai:

$text = 'Works like magick!';
$image->Annotate(font=>'kai.ttf', pointsize=>40, fill=>'green', text=>$text);

Barangkali Anda ingin mengekstrak semua intensitas piksel dari gambar dan menuliskannya ke STDOUT:

@pixels = $image->GetPixels(map=>'I', height=>$height, width=>$width, normalize=>true);
binmode STDOUT;
print pack('B*',join('',@pixels));

Hal-hal cerdas lain yang dapat Anda lakukan dengan objek PerlMagick meliputi

$i = $#$p"+1";   # mengembalikan jumlah gambar yang terkait dengan objek p
push(@$q, @$p);  # push gambar dari objek p ke objek q
@$p = ();        # menghapus gambar tetapi tidak objek p
$p->Convolve([1, 2, 1, 2, 4, 2, 1, 2, 1]);   # kernel Gauss 3x3

Membaca atau menulis gambar

Gunakan metode yang tercantum di bawah ini untuk membaca, menulis, atau menampilkan gambar atau urutan gambar:

Untuk kemudahan, metode Write(), Display(), dan Animate() dapat menerima parameter apa pun yang dikenali oleh SetAttribute. Misalnya,

$image->Write(filename=>'image.png', compression=>'None');

Gunakan - sebagai nama file untuk metode Read() agar membaca dari standard in, atau untuk metode Write() agar menulis ke standard out:

binmode STDOUT;
$image->Write('png:-');

Untuk membaca gambar berformat GIF dari filehandle PERL, gunakan:

$image = Image::Magick->new;
open(IMAGE, 'image.gif');
$image->Read(file=>\*IMAGE);
close(IMAGE);

Untuk menulis gambar berformat PNG ke filehandle PERL, gunakan:

$filename = "image.png";
open(IMAGE, ">$filename");
$image->Write(file=>\*IMAGE, filename=>$filename);
close(IMAGE);

Perlu diperhatikan, membaca dari atau menulis ke filehandle Perl dapat gagal pada Windows karena perbedaan versi pustaka (library) C-runtime antara ImageMagick dan distribusi ActiveState Perl, atau jika salah satu DLL ditautkan dengan opsi /MT. Lihat Potential Errors Passing CRT Objects Across DLL Boundaries untuk penjelasannya.

Jika %0Nd, %0No, atau %0Nx muncul dalam nama file, ini akan diinterpretasikan sebagai spesifikasi format printf, dan spesifikasi tersebut digantikan dengan encoding desimal, oktal, atau heksadesimal dari nomor scene yang ditentukan. Misalnya,

image%03d.miff

mengonversi file image000.miff, image001.miff, dst.

Anda dapat secara opsional menambahkan Image ke nama metode apa pun. Misalnya, ReadImage() adalah alias untuk metode Read().

Memanipulasi gambar

Setelah Anda membuat gambar, misalnya dengan metode ReadImage(), Anda mungkin ingin mengoperasikannya. Berikut adalah daftar semua metode manipulasi gambar yang tersedia untuk Anda di PerlMagick. Ada contoh beberapa metode PerlMagick pilihan. Berikut adalah contoh pemanggilan metode manipulasi gambar:

$image->Crop(geometry=>'100x100+10+20');
$image->[$x]->Frame("100x200");

Dan berikut adalah daftar metode manipulasi gambar lain yang dapat Anda panggil:

Perlu diperhatikan, parameter geometry adalah singkatan untuk parameter width dan height (misalnya geometry=>'106x80' setara dengan width=>106, height=>80 ).

Anda dapat menentukan @filename baik pada Annotate() maupun Draw(). Ini membaca instruksi teks atau primitif grafis dari file pada disk. Misalnya,

image->Draw(fill=>'red', primitive=>'rectangle',
 points=>'20,20 100,100  40,40 200,200  60,60 300,300');

Setara dengan

$image->Draw(fill=>'red', primitive=>'@draw.txt');

Di mana draw.txt adalah file pada disk yang berisi ini:

rectangle 20, 20 100, 100
rectangle 40, 40 200, 200
rectangle 60, 60 300, 300

Parameter text untuk metode Annotate(), Comment(), Draw(), dan Label() dapat menyertakan nama file gambar, tipe, lebar, tinggi, atau atribut gambar lainnya dengan menyisipkan karakter format khusus berikut:

%b   ukuran file
%c   komentar
%d   direktori
%e   ekstensi nama file
%f   nama file
%g   geometri halaman
%h   tinggi
%i   nama file input
%k   jumlah warna unik
%l   label
%m   magick
%n   jumlah scene
%o   nama file output
%p   nomor halaman
%q   kedalaman quantum
%r   kelas gambar dan ruang warna
%s   nomor scene
%t   bagian awal nama file
%u   nama file sementara unik
%w   lebar
%x   resolusi x
%y   resolusi y
%z   kedalaman gambar
%C   jenis kompresi gambar
%D   metode dispose gambar
%H   tinggi halaman
%Q   kualitas kompresi gambar
%T   delay gambar
%W   lebar halaman
%X   offset x halaman
%Y   offset y halaman
%@   bounding box
%#   signature
%%   tanda persen
\n   baris baru (newline)
\r   carriage return

Misalnya,

text=>"%m:%f %wx%h"

menghasilkan anotasi MIFF:bird.miff 512x480 untuk gambar berjudul bird.miff yang lebarnya 512 dan tingginya 480.

Anda dapat secara opsional menambahkan Image ke nama metode apa pun. Misalnya, TrimImage() adalah alias untuk metode Trim().

Sebagian besar atribut yang tercantum di atas memiliki padanan dalam magick. Lihat dokumentasi untuk deskripsi yang lebih rinci tentang atribut-atribut ini.

Mengatur atribut gambar

Gunakan metode Set() untuk mengatur atribut gambar. Misalnya,

$image->Set(dither=>'True');
$image->[$x]->Set(delay=>3);

Ketika contoh ini menggunakan 'True' dan dokumen ini menyebutkan '{True, False}', Anda dapat menggunakan string 'True' dan 'False' yang tidak peka huruf besar/kecil (case-insensitive), atau Anda dapat menggunakan bilangan bulat 1 dan 0.

Ketika Anda memanggil Get() pada atribut Boolean, Image::Magick mengembalikan 1 atau 0, bukan string.

Dan berikut adalah daftar semua atribut gambar yang dapat Anda atur:

Perlu diperhatikan, parameter geometry adalah singkatan untuk parameter width dan height (misalnya geometry=>'106x80' setara dengan width=>106, height=>80).

SetAttribute() adalah alias untuk metode Set().

Sebagian besar atribut yang tercantum di atas memiliki padanan dalam magick. Lihat dokumentasi untuk deskripsi yang lebih rinci tentang atribut-atribut ini.

Mendapatkan atribut gambar

Gunakan metode Get() untuk mendapatkan atribut gambar. Misalnya,

($a, $b, $c) = $image->Get('colorspace', 'magick', 'adjoin');
$width = $image->[3]->Get('columns');

Selain semua atribut yang tercantum dalam Mengatur atribut gambar, Anda dapat mendapatkan atribut tambahan berikut:

GetAttribute() adalah alias untuk metode Get().

Sebagian besar atribut yang tercantum di atas memiliki padanan dalam magick. Lihat dokumentasi untuk deskripsi yang lebih rinci tentang atribut-atribut ini.

Membandingkan gambar dengan rekonstruksinya

Secara matematis dan visual, beri anotasi perbedaan antara gambar dan rekonstruksinya dengan metode Compare(). Metode ini mendukung parameter berikut:

Pada contoh ini, kita membandingkan logo ImageMagick dengan rekonstruksi yang telah ditajamkan:

use Image::Magick;

$logo=Image::Magick->New();
$logo->Read('logo:');
$sharp=Image::Magick->New();
$sharp->Read('logo:');
$sharp->Sharpen('0x1');
$difference=$logo->Compare(image=>$sharp, metric=>'rmse');
print $difference->Get('error'), "\n";
$difference->Display();

Selain root mean squared error yang dilaporkan sekitar 0.024, gambar perbedaan juga ditampilkan sehingga Anda dapat mengidentifikasi perbedaan antar gambar secara visual.

Membuat montase gambar

Gunakan metode Montage() untuk membuat gambar komposit dengan menggabungkan beberapa gambar terpisah. Gambar-gambar tersebut disusun sebagai tile pada gambar komposit, dengan nama gambar yang secara opsional muncul tepat di bawah masing-masing tile. Misalnya,

$image->Montage(geometry=>'160x160', tile=>'2x2', texture=>'granite:');

Dan berikut adalah daftar parameter Montage() yang dapat Anda atur:

Perlu diperhatikan, parameter geometry adalah singkatan untuk parameter width dan height (misalnya geometry=>'106x80' setara dengan width=>106, height=>80).

MontageImage() adalah alias untuk metode Montage().

Sebagian besar atribut yang tercantum di atas memiliki padanan dalam montage. Lihat dokumentasi untuk deskripsi yang lebih rinci tentang atribut-atribut ini.

Bekerja dengan blob

Blob berisi data yang secara langsung merepresentasikan format gambar tertentu di dalam memori, bukan di disk. PerlMagick mendukung blob dalam salah satu format gambar berikut dan menyediakan metode untuk mengonversi blob ke atau dari format gambar tertentu.

ImageToBlob() mengembalikan data gambar dalam format masing-masing. Anda kemudian dapat mencetaknya, menyimpannya ke basis data ODBC, menuliskannya ke file, atau mem-pipe-nya ke program display:

@blobs = $image->ImageToBlob();
open(DISPLAY,"| display -") || die;
binmode DISPLAY;
print DISPLAY $blobs[0];
close DISPLAY;

Metode BlobToImage() mengembalikan gambar atau urutan gambar yang dikonversi dari blob yang diberikan:

@blob=$db->GetImage();
$image=Image::Magick->new(magick=>'jpg');
$image->BlobToImage(@blob);

Akses langsung ke piksel gambar

Gunakan metode berikut untuk mendapatkan akses langsung ke piksel gambar:

Metode lain-lain

Metode Append() menggabungkan sekumpulan gambar. Misalnya,

$p = $image->Append(stack=>{true,false});

menggabungkan semua gambar yang terkait dengan objek $image. Secara default, gambar disusun dari kiri ke kanan. Atur stack ke True untuk menyusunnya dari atas ke bawah.

Metode Clone() menyalin sekumpulan gambar. Misalnya,

$q = $p->Clone();

menyalin semua gambar dari objek $p ke $q. Anda dapat menggunakan metode ini untuk urutan gambar tunggal maupun multi-gambar.

Coalesce() mengomposisikan sekumpulan gambar dengan tetap memperhatikan offset halaman dan metode disposal. Urutan animasi GIF, MIFF, dan MNG biasanya dimulai dengan gambar latar belakang, dan setiap gambar berikutnya bervariasi dalam ukuran dan offset. Urutan gambar baru dikembalikan dengan semua gambar berukuran sama seperti kanvas virtual gambar pertama dan dikomposisikan dengan gambar berikutnya dalam urutan.. Misalnya,

$q = $p->Coalesce();

Metode ComplexImages() melakukan operasi matematika kompleks pada urutan gambar. Misalnya,

$p = $image->ComplexImages('conjugate');

Metode EvaluateImages() menerapkan ekspresi aritmetika, logika, atau relasional pada sekumpulan gambar. Misalnya,

$p = $image->EvaluateImages('mean');

merata-ratakan semua gambar yang terkait dengan objek $image.

Metode Features() mengembalikan fitur untuk setiap kanal pada gambar dalam masing-masing dari empat arah (horizontal, vertikal, diagonal kiri dan kanan) untuk jarak yang ditentukan. Fitur tersebut meliputi angular second momentum, contrast, correlation, sum of squares: variance, inverse difference moment, sum average, sum variance, sum entropy, entropy, difference variance, difference entropy, information measures of correlation 1, information measures of correlation 2, dan maximum correlation coefficient. Nilai dalam urutan RGB, CMYK, RGBA, atau CMYKA (tergantung jenis gambar).

@features = $image->Features(1);

Metode Flatten() meratakan (flatten) sekumpulan gambar dan mengembalikannya. Misalnya,

$p = $images->Flatten(background=>'none');
$p->Write('flatten.png');

Urutan gambar digantikan oleh satu gambar yang dibuat dengan mengomposisikan setiap gambar setelah gambar pertama di atas gambar pertama.

Metode Fx() menerapkan ekspresi matematika pada sekumpulan gambar dan mengembalikan hasilnya. Misalnya,

$p = $image->Fx(expression=>'(g+b)/2.0',channel=>'red');
$p->Write('fx.miff');

mengganti kanal merah dengan rata-rata kanal hijau dan biru.

Lihat FX, operator gambar efek khusus untuk pembahasan rinci tentang metode ini.

Histogram() mengembalikan warna unik pada gambar beserta jumlah masing-masing warna. Nilai yang dikembalikan berupa array nilai red, green, blue, opacity, dan count.

Metode Morph() melakukan morphing pada sekumpulan gambar. Baik piksel maupun ukuran gambar diinterpolasi secara linear untuk memberikan tampilan meta-morfosis dari satu gambar ke gambar berikutnya:

$p = $image->Morph(frames=>_integer_);

di mana frames adalah jumlah gambar antara yang akan dihasilkan. Nilai defaultnya adalah 1.

Mosaic() membuat mosaik dari urutan gambar.

Metode Mogrify() adalah satu titik masuk tunggal untuk metode-metode manipulasi gambar (Memanipulasi gambar). Parameternya adalah nama metode diikuti oleh parameter apa pun yang mungkin dibutuhkan metode tersebut. Misalnya, kedua pemanggilan berikut setara:

$image->Crop('340x256+0+0');
$image->Mogrify('crop', '340x256+0+0');

Metode MogrifyRegion() menerapkan transformasi pada suatu wilayah gambar. Metode ini mirip dengan Mogrify() tetapi diawali dengan geometri wilayah. Misalnya, misalkan Anda ingin mencerahkan wilayah 100x100 pada gambar Anda di lokasi (40, 50):

$image->MogrifyRegion('100x100+40+50', 'modulate', brightness=>50);

PerceptualHash() memetakan gambar yang identik secara visual ke hash yang sama atau serupa -- berguna untuk pencarian gambar (image retrieval), autentikasi, pengindeksan, atau deteksi salinan, serta watermarking digital. Untuk setiap kanal dan untuk ruang warna sRGB dan HCLp, 7 nilai hash dikembalikan. Untuk gambar sRGB, misalnya, diharapkan ada 42 perceptual hash.

@phash = $image->PerceptualHash();

Ping() adalah metode praktis yang mengembalikan informasi tentang gambar tanpa perlu membaca gambar ke dalam memori. Metode ini mengembalikan lebar, tinggi, ukuran file dalam byte, dan format file gambar. Anda dapat menentukan lebih dari satu nama file, tetapi hanya satu filehandle:

($width, $height, $size, $format) = $image->Ping('logo.png');
($width, $height, $size, $format) = $image->Ping(file=>\*IMAGE);
($width, $height, $size, $format) = $image->Ping(blob=>$blob);

Ini adalah cara yang lebih efisien dan lebih hemat memori untuk memeriksa apakah suatu gambar ada dan bagaimana karakteristiknya.

Poly() membangun polinomial dari urutan gambar dan suku-suku terkait (pasangan koefisien dan derajat):

$p = $image->Poly([0.5,1.0,0.25,2.0,1.0,1.0]);

PreviewImage() menyusun 9 thumbnail dari gambar yang ditentukan dengan operasi pemrosesan gambar yang diterapkan pada berbagai tingkat kekuatan. Ini dapat membantu menentukan parameter yang tepat untuk operasi pemrosesan gambar tertentu. Pilih dari operasi berikut: Rotate, Shear, Roll, Hue, Saturation, Brightness, Gamma, Spiff, Dull, Grayscale, Quantize, Despeckle, ReduceNoise, AddNoise, Sharpen, Blur, Threshold, EdgeDetect, Spread, Solarize, Shade, Raise, Segment, Swirl, Implode, Wave, OilPaint, CharcoalDrawing, JPEG. Berikut contohnya:

$preview = $image->Preview('Gamma');
$preview->Display();

Untuk memiliki kendali penuh atas penempatan teks, Anda memerlukan informasi metrik font. Gunakan

($x_ppem, $y_ppem, $ascender, $descender, $width, $height, $max_advance) =
  $image->QueryFontMetrics(_parameters_);

Di mana parameters adalah parameter apa pun dari metode Annotate. Nilai yang dikembalikan adalah:

1. lebar karakter
2. tinggi karakter
3. ascender
4. descender
5. lebar teks
6. tinggi teks
7. horizontal advance maksimum
8. bounds: x1
9. bounds: y1
10. bounds: x2
11. bounds: y2
12. origin: x
13. origin: y

Gunakan QueryMultilineFontMetrics() untuk mendapatkan lebar dan tinggi teks maksimum untuk beberapa baris teks.

Panggil QueryColor() tanpa parameter untuk mengembalikan daftar nama warna yang dikenal, atau tentukan satu atau lebih nama warna untuk mendapatkan atribut berikut: nilai red, green, blue, dan opacity.

@colors = $image->QueryColor();
($red, $green, $blue) = $image->QueryColor('cyan');
($red, $green, $blue, $alpha) = $image->QueryColor('#716baeff');

QueryColorname() menerima nilai warna dan mengembalikan nama atau nilai hex yang sesuai;

$name = $image->QueryColorname('rgba(80,60,0,0)');

Panggil QueryFont() tanpa parameter untuk mengembalikan daftar font yang dikenal, atau tentukan satu atau lebih nama font untuk mendapatkan atribut berikut: nilai font name, description, family, style, stretch, weight, encoding, foundry, format, metrics, dan glyphs.

@fonts = $image->QueryFont();
$weight = ($image->QueryFont('Helvetica'))[5];

Panggil QueryFormat() tanpa parameter untuk mengembalikan daftar format gambar yang dikenal, atau tentukan satu atau lebih nama format untuk mendapatkan atribut berikut: adjoin, blob support, raw, decoder, encoder, description, dan module.

@formats = $image->QueryFormat();
($adjoin, $blob_support, $raw, $decoder, $encoder, $description, $module) =
  $image->QueryFormat('gif');

Panggil MagickToMime() dengan nama format gambar untuk mendapatkan tipe MIME-nya, seperti image/tiff dari tif.

$mime = $image->MagickToMime('tif');

Gunakan RemoteCommand() untuk mengirim perintah ke aplikasi display atau animate yang sudah berjalan. Satu-satunya parameter adalah nama file gambar yang akan ditampilkan atau dianimasikan.

$image->RemoteCommand('image.jpg');

Metode Smush() menggabungkan (smush) sekumpulan gambar bersama-sama. Misalnya,

$p = $image->Smush(stack=>{true,false},offset=>integer);

menggabungkan bersama semua gambar yang terkait dengan objek $image. Secara default, gambar digabungkan dari kiri ke kanan. Atur stack ke True untuk menggabungkannya dari atas ke bawah.

Statistics() mengembalikan statistik gambar untuk setiap kanal pada gambar. Nilai yang dikembalikan berupa array nilai depth, minima, maxima, mean, standard deviation, kurtosis, skewness, dan entropy dalam urutan RGB, CMYK, RGBA, atau CMYKA (tergantung jenis gambar).

@statistics = $image->Statistics();

Terakhir, metode Transform() menerima spesifikasi geometry yang lengkap untuk memangkas atau mengubah ukuran satu atau lebih gambar. Misalnya,

$p = $image->Transform(crop=>'100x100+0+0');

Anda dapat secara opsional menambahkan Image ke nama metode apa pun di atas. Misalnya, PingImage() adalah alias untuk metode Ping().

Menangani exception

Semua metode PerlMagick mengembalikan konteks string undefined saat berhasil. Jika terjadi masalah, error dikembalikan sebagai string dengan kode status numerik yang disematkan. Kode status kurang dari 400 adalah warning. Ini berarti operasi tidak selesai tetapi masih dapat dipulihkan sampai tingkat tertentu. Kode numerik yang sama dengan atau lebih besar dari 400 adalah error dan menunjukkan operasi gagal sepenuhnya. Berikut adalah cara exception dikembalikan untuk metode yang berbeda-beda:

Metode yang mengembalikan angka (misalnya Read(), Write()):

$x = $image->Read(...);
warn "$x" if "$x";      # mencetak pesan error
$x =~ /(\d+)/;
print $1;               # mencetak nomor error
print 0+$x;             # mencetak jumlah gambar yang dibaca

Metode yang beroperasi pada gambar (misalnya Resize(), Crop()):

$x = $image->Crop(...);
warn "$x" if "$x";      # mencetak pesan error
$x =~ /(\d+)/;
print $1;               # mencetak nomor error

Metode yang mengembalikan gambar (EvaluateSequence(), Montage(), Clone()) sebaiknya diperiksa kesalahannya dengan cara berikut:

$x = $image->Montage(...);
warn "$x" if !ref($x);  # mencetak pesan error
$x =~ /(\d+)/;
print $1;               # mencetak nomor error

Berikut adalah contoh pesan error:

Error 400: Memory allocation failed

Lihat daftar lengkap kode error dan warning.

Berikut ini menggambarkan cara Anda dapat menggunakan kode status numerik:

$x = $image->Read('rose.png');
$x =~ /(\d+)/;
die "unable to continue" if ($1 == ResourceLimitError);

Konstanta

PerlMagick menyertakan konstanta berikut:

BlobError
BlobWarning
CacheError
CacheWarning
CoderError
CoderWarning
ConfigureError
ConfigureWarning
CorruptImageError
CorruptImageWarning
DelegateError
DelegateWarning
DrawError
DrawWarning
ErrorException
FatalErrorException
FileOpenError
FileOpenWarning
ImageError
ImageWarning
MissingDelegateError
MissingDelegateWarning
ModuleError
ModuleWarning
Opaque
OptionError
OptionWarning
QuantumDepth
QuantumRange
RegistryError
RegistryWarning
ResourceLimitError
ResourceLimitWarning
StreamError
StreamWarning
Success
Transparent
TypeError
TypeWarning
WarningException
XServerError
XServerWarning

Anda dapat mengaksesnya seperti ini:

Image::Magick->QuantumDepth