インストール • 概要 • サンプルスクリプト • 画像の読み書き • 画像の操作 • 画像属性の設定 • 画像属性の取得 • 画像と再構成の比較 • 画像モンタージュの作成 • Blob の扱い • 画像画素への直接アクセス • その他のメソッド • 例外処理 • 定数

PerlMagick は ImageMagick へのオブジェクト指向の Perl インターフェイスです。このモジュールを使って、Perl スクリプト内から画像や画像シーケンスを読み込み・操作・書き出しできます。これは Web CGI スクリプトに非常に適しています。PerlMagick を正しくビルドするには、システムに ImageMagick 6.5.5 以上と Perl バージョン 5.005_02 以上がインストールされている必要があります。

PerlMagick の価値を示す有用なスクリプトが多数あります。MagickStudio で Web ベースの画像操作・変換ができますし、L-systems で数学的構成を使って植物の画像を作成したり、WebMagick Image Navigator でサムネイル画像のコレクションをたどって表示する画像を選んだりできます。

Web ブラウザから ImageMagick Studio で PerlMagick を試せます。あるいは、選り抜きの PerlMagick 関数の 例 を見られます。

インストール

UNIX

PerlMagick はシステムの RPM リポジトリから入手できますか? たとえば私たちの CentOS システムでは、PerlMagick を次のようにインストールします。

yum install ImageMagick-perl

入手できない場合、ImageMagick ソース配布物から PerlMagick をインストールする必要があります。最新の ソース リリースをダウンロードします。

次のコマンドで配布物を展開します。

tar xvzf ImageMagick.tar.gz

次に ImageMagick を構成・コンパイルします。

cd ImageMagick-7.1.2-25
./configure -with-perl
make

ImageMagick / PerlMagick が問題なく構成・コンパイルされたら、システムにインストールする準備ができています。インストールには管理者権限が必要です。インストールするには次を入力します。

sudo make install

動的リンカの実行時バインディングを構成する必要があるかもしれません。

sudo ldconfig /usr/local/lib

最後に、PerlMagick のインストールが正しく機能したか確認するため、次を入力します。

perl -MImage::Magick -le 'print Image::Magick->QuantumDepth'

おめでとうございます。動作する ImageMagick 配布物が手に入り、PerlMagick を使って画像を 変換・合成・編集 する準備ができました。

Windows XP / Windows 2000

システムに ImageMagick がすでにインストールされている必要があります。また、Windows 2000 用の ImageMagick ソース配布物が必要です。Visual C++ または J++ 開発環境の nmake も必要です。\bin\IMagick.dll と \bin\X11.dll を、c:\perl\site\5.00502 などの動的ロードパス内のディレクトリへコピーします。

次に、次を入力します。

cd PerlMagick
perl Makefile.nt
nmake
nmake install

回帰テストの実行

正しいインストールを確認するには、次を入力します。

make test

Windows では nmake test を使います。PerlMagick が実行できる多くの関数を試すデモスクリプトがいくつかあります。

ビルドフォルダからテストを実行するには prove ユーティリティを使います。

prove --blib blib -I `pwd` -bv ./t/read.t



cd demo
make

これで Perl スクリプト内から PerlMagick メソッドを利用する準備ができました。

概要

PerlMagick メソッドを使いたいスクリプトはすべて、まず名前空間内にメソッドを定義し、画像オブジェクトをインスタンス化する必要があります。次のように行います。

use Image::Magick;

$image = Image::Magick->new;

PerlMagick は量子を認識します。画像オブジェクトをインスタンス化する際に特定の量子深度を要求できます。

use Image::Magick::Q16;

$image = Image::Magick::Q16->new;

new() メソッドは SetAttribute と同じパラメータを取ります。たとえば、

$image = Image::Magick->new(size=>'384x256');

次に画像または画像シーケンスを読み込み、操作し、表示または書き出したくなるでしょう。PerlMagick の入出力メソッドは「画像の読み書き」で定義されています。画像の読み書きの方法に影響するメソッドは「画像属性の設定」を参照してください。画像を変換するメソッドの一覧は「画像の操作」を参照してください。「画像属性の取得」では画像の属性を取得する方法を説明します。背景上にサムネイルとして画像をタイル状に並べる詳細は「画像モンタージュの作成」を参照してください。最後に、上記のどのカテゴリにもうまく収まらないメソッドもあります。これらのメソッドの一覧は「その他のメソッド」を参照してください。

PerlMagick オブジェクトを使い終えたら破棄を検討すべきです。画像シーケンス内の各画像は仮想メモリに格納されます。これは潜在的に数メビバイトのメモリに達することがあります。PerlMagick オブジェクトを破棄すると、メモリは他の Perl メソッドが使えるよう返却されます。オブジェクトを破棄する推奨方法は undef です。

undef $image;

Image::Magick オブジェクトを保持しつつすべての画像を削除するには次を使います。

@$image = ();

そして、マルチイメージシーケンスから単一の画像を削除するには次を使います。

undef $image->[$x];

次のセクションでは、さまざまな PerlMagick メソッドを使って画像シーケンスを操作する方法を示します。

一部の PerlMagick メソッドは Ghostscript などの外部プログラムを必要とします。正しく動作するには PATH 環境変数に明示的なパスが必要なことがあります。たとえば(Linux では)、

$ENV{PATH}' . "='/../bin:/usr/bin:/usr/local/bin';

サンプルスクリプト

手始めとなるサンプルスクリプトを示します。

 1
 2
 3
 4
 5
 6
 7
 8
 9
10
11
12
13
14

#!/usr/local/bin/perl
use Image::Magick;

my($image, $x);

$image = Image::Magick->new;
$x = $image->Read('girl.png', 'logo.png', 'rose.png');
warn "$x" if "$x";

$x = $image->Crop(geometry=>'100x100+100+100');
warn "$x" if "$x";

$x = $image->Write('x.png');
warn "$x" if "$x";

このスクリプトは 3 つの画像を読み込み、切り抜き、単一の画像を GIF アニメーションシーケンスとして書き出します。多くの場合、シーケンスの個々の画像へアクセスしたいでしょう。次の例はその方法を示します。

 1
 2
 3
 4
 5
 6
 7
 8
 9
10
11
12
13
14
15
16
17
18
19
20

#!/usr/local/bin/perl
use Image::Magick;

my($image, $p, $q);

$image = new Image::Magick;
$image->Read('x1.png');
$image->Read('j*.jpg');
$image->Read('k.miff[1, 5, 3]');
$image->Contrast();
for ($x = 0; $image->[$x]; $x++)
{
  $image->[$x]->Frame('100x200') if $image->[$x]->Get('magick') eq 'GIF';
  undef $image->[$x] if $image->[$x]->Get('columns') < 100;
}
$p = $image->[1];
$p->Draw(stroke=>'red', primitive=>'rectangle', points=>20,20 100,100');
$q = $p->Montage();
undef $image;
$q->Write('x.miff');

中央に赤い画素を持つ 100x100 ピクセルの白いキャンバスから始めたいとします。次を試します。

$image = Image::Magick->new;
$image->Set(size=>'100x100');
$image->ReadImage('canvas:white');
$image->Set('pixel[49,49]'=>'red');

ここでは (1,1) の赤成分の強度を半分に減らします。

@pixels = $image->GetPixel(x=>1,y=>1);
$pixels[0]*=0.5;
$image->SetPixel(x=>1,y=>1,color=>\@pixels);

あるいはカラー画像をグレースケールへ変換したいとします。

$image->Quantize(colorspace=>'gray');

台北の TrueType フォントで画像に注釈を付けてみましょう。

$text = 'Works like magick!';
$image->Annotate(font=>'kai.ttf', pointsize=>40, fill=>'green', text=>$text);

画像からすべての画素強度を抽出して STDOUT へ書き出したいかもしれません。

@pixels = $image->GetPixels(map=>'I', height=>$height, width=>$width, normalize=>true);
binmode STDOUT;
print pack('B*',join('',@pixels));

PerlMagick オブジェクトでできる他の巧妙なことには次があります。

$i = $#$p"+1";   # オブジェクト p に関連付けられた画像数を返す
push(@$q, @$p);  # オブジェクト p の画像をオブジェクト q へプッシュする
@$p = ();        # 画像を削除するがオブジェクト p は削除しない
$p->Convolve([1, 2, 1, 2, 4, 2, 1, 2, 1]);   # 3x3 ガウシアンカーネル

画像の読み書き

以下のメソッドを使って、画像または画像シーケンスを読み込む・書き出す・表示します。

便宜上、Write()・Display()・Animate() メソッドは SetAttribute が知っている任意のパラメータを取れます。たとえば、

$image->Write(filename=>'image.png', compression=>'None');

標準入力から読み込むには Read() メソッドに、標準出力へ書き出すには Write() メソッドに、ファイル名として - を使います。

binmode STDOUT;
$image->Write('png:-');

PERL ファイルハンドルから GIF 形式の画像を読み込むには次を使います。

$image = Image::Magick->new;
open(IMAGE, 'image.gif');
$image->Read(file=>\*IMAGE);
close(IMAGE);

PERL ファイルハンドルへ PNG 形式の画像を書き出すには次を使います。

$filename = "image.png";
open(IMAGE, ">$filename");
$image->Write(file=>\*IMAGE, filename=>$filename);
close(IMAGE);

なお、Perl ファイルハンドルからの読み書きは、ImageMagick と ActiveState Perl 配布物の間で C ランタイムライブラリのバージョンが異なる場合や、DLL の 1 つが /MT オプションでリンクされている場合、Windows で失敗することがあります。説明は Potential Errors Passing CRT Objects Across DLL Boundaries を参照してください。

ファイル名に %0Nd・%0No・%0Nx が現れると、printf 書式指定として解釈され、その指定はシーン番号の指定された 10 進・8 進・16 進エンコードに置き換えられます。たとえば、

image%03d.miff

はファイル image000.miff・image001.miff などを変換します。

任意のメソッド名に Image を追加できます。たとえば ReadImage() は Read() メソッドの別名です。

画像の操作

たとえば ReadImage() メソッドで画像を作成したら、それに対して操作したくなるでしょう。以下は PerlMagick で利用できるすべての画像操作メソッドの一覧です。選り抜きの PerlMagick メソッドの 例 があります。画像操作メソッドの呼び出し例を示します。

$image->Crop(geometry=>'100x100+10+20');
$image->[$x]->Frame("100x200");

そして、呼び出せる他の画像操作メソッドの一覧を示します。

なお、geometry パラメータは width と height パラメータの短縮形です(例: geometry=>'106x80' は width=>106, height=>80 と等価)。

Annotate() と Draw() の両方で @filename を指定できます。これはディスク上のファイルからテキストまたはグラフィックプリミティブの指示を読み込みます。たとえば、

image->Draw(fill=>'red', primitive=>'rectangle',
 points=>'20,20 100,100  40,40 200,200  60,60 300,300');

は次と等価です。

$image->Draw(fill=>'red', primitive=>'@draw.txt');

ここで draw.txt は次を含むディスク上のファイルです。

rectangle 20, 20 100, 100
rectangle 40, 40 200, 200
rectangle 60, 60 300, 300

Annotate()・Comment()・Draw()・Label() メソッドの text パラメータには、以下の特殊な書式文字を埋め込むことで、画像のファイル名・タイプ・幅・高さなどの画像属性を含められます。

%b   ファイルサイズ
%c   コメント
%d   ディレクトリ
%e   ファイル名の拡張子
%f   ファイル名
%g   ページジオメトリ
%h   高さ
%i   入力ファイル名
%k   一意な色の数
%l   ラベル
%m   magick
%n   シーン数
%o   出力ファイル名
%p   ページ番号
%q   量子深度
%r   画像クラスとカラースペース
%s   シーン番号
%t   ディレクトリ・拡張子を除いたファイル名
%u   一意な一時ファイル名
%w   幅
%x   x 解像度
%y   y 解像度
%z   画像深度
%C   画像圧縮タイプ
%D   画像 dispose メソッド
%H   ページ高さ
%Q   画像圧縮品質
%T   画像遅延
%W   ページ幅
%X   ページ x オフセット
%Y   ページ y オフセット
%@   境界ボックス
%#   シグネチャ
%%   パーセント記号
\n   改行
\r   キャリッジリターン

たとえば、

text=>"%m:%f %wx%h"

は、タイトルが bird.miff で幅 512・高さ 480 の画像に対して MIFF:bird.miff 512x480 という注釈を生成します。

任意のメソッド名に Image を追加できます。たとえば TrimImage() は Trim() メソッドの別名です。

上記の属性のほとんどは magick に対応するものがあります。これらの属性のより詳細な説明はドキュメントを参照してください。

画像属性の設定

画像属性を設定するには Set() メソッドを使います。たとえば、

$image->Set(dither=>'True');
$image->[$x]->Set(delay=>3);

この例で 'True' を使い、本ドキュメントが '{True, False}' と記している箇所では、大文字小文字を区別しない文字列 'True'・'False' を使うか、整数 1・0 を使えます。

Boolean 属性に Get() を呼ぶと、Image::Magick は文字列ではなく 1 または 0 を返します。

そして、設定できるすべての画像属性の一覧を示します。

なお、geometry パラメータは width と height パラメータの短縮形です(例: geometry=>'106x80' は width=>106, height=>80 と等価)。

SetAttribute() は Set() メソッドの別名です。

上記の属性のほとんどは magick に対応するものがあります。これらの属性のより詳細な説明はドキュメントを参照してください。

画像属性の取得

画像属性を取得するには Get() メソッドを使います。たとえば、

($a, $b, $c) = $image->Get('colorspace', 'magick', 'adjoin');
$width = $image->[3]->Get('columns');

「画像属性の設定」に挙げたすべての属性に加えて、以下の追加属性を取得できます。

GetAttribute() は Get() メソッドの別名です。

上記の属性のほとんどは magick に対応するものがあります。これらの属性のより詳細な説明はドキュメントを参照してください。

画像と再構成の比較

Compare() メソッドで、画像とその再構成の差を数学的・視覚的に注釈します。このメソッドは以下のパラメータをサポートします。

この例では、ImageMagick ロゴをシャープにした再構成と比較します。

use Image::Magick;

$logo=Image::Magick->New();
$logo->Read('logo:');
$sharp=Image::Magick->New();
$sharp->Read('logo:');
$sharp->Sharpen('0x1');
$difference=$logo->Compare(image=>$sharp, metric=>'rmse');
print $difference->Get('error'), "\n";
$difference->Display();

報告される約 0.024 の二乗平均平方根誤差に加えて、差分画像が表示され、画像間の差を視覚的に確認できます。

画像モンタージュの作成

複数の別個の画像を組み合わせて合成画像を作成するには Montage() メソッドを使います。画像は合成画像上にタイル状に並べられ、任意で各タイルのすぐ下に画像名が表示されます。たとえば、

$image->Montage(geometry=>'160x160', tile=>'2x2', texture=>'granite:');

そして、設定できる Montage() パラメータの一覧を示します。

なお、geometry パラメータは width と height パラメータの短縮形です(例: geometry=>'106x80' は width=>106, height=>80 と等価)。

MontageImage() は Montage() メソッドの別名です。

上記の属性のほとんどは montage に対応するものがあります。これらの属性のより詳細な説明はドキュメントを参照してください。

Blob の扱い

blob は、ディスク上ではなくメモリ内で特定の画像形式を直接表すデータを含みます。PerlMagick は任意の画像 形式 で blob をサポートし、blob を特定の画像形式へ/から変換するメソッドを提供します。

ImageToBlob() はそれぞれの形式の画像データを返します。それを出力したり、ODBC データベースへ保存したり、ファイルへ書き出したり、表示プログラムへパイプしたりできます。

@blobs = $image->ImageToBlob();
open(DISPLAY,"| display -") || die;
binmode DISPLAY;
print DISPLAY $blobs[0];
close DISPLAY;

BlobToImage() メソッドは、与えられた blob から変換された画像または画像シーケンスを返します。

@blob=$db->GetImage();
$image=Image::Magick->new(magick=>'jpg');
$image->BlobToImage(@blob);

画像画素への直接アクセス

画像画素への直接アクセスを得るには以下のメソッドを使います。

その他のメソッド

Append() メソッドは画像のセットを連結します。たとえば、

$p = $image->Append(stack=>{true,false});

はオブジェクト $image に関連付けられたすべての画像を連結します。デフォルトでは画像は左から右へ積まれます。上から下へ積むには stack を True にします。

Clone() メソッドは画像のセットをコピーします。たとえば、

$q = $p->Clone();

はオブジェクト $p のすべての画像を $q へコピーします。単一・マルチイメージシーケンスのどちらにも使えます。

Coalesce() は、ページオフセットと dispose メソッドを尊重しながら画像のセットを合成します。GIF・MIFF・MNG アニメーションシーケンスは通常、画像背景で始まり、後続の各画像はサイズとオフセットが異なります。すべての画像が最初の画像の仮想キャンバスと同じサイズになり、シーケンス内の次の画像と合成された、新しい画像シーケンスが返されます。たとえば、

$q = $p->Coalesce();

ComplexImages() メソッドは画像シーケンスに複素数演算を行います。たとえば、

$p = $image->ComplexImages('conjugate');

EvaluateImages() メソッドは画像のセットに算術・論理・関係式を適用します。たとえば、

$p = $image->EvaluateImages('mean');

はオブジェクト $image に関連付けられたすべての画像を平均します。

Features() メソッドは、指定の距離について、画像内の各チャンネルの特徴量を 4 方向(水平・垂直・左右の対角)それぞれで返します。特徴量には、角度二次モーメント・コントラスト・相関・二乗和(分散)・逆差分モーメント・和平均・和分散・和エントロピー・エントロピー・差分散・差エントロピー・相関の情報尺度 1・相関の情報尺度 2・最大相関係数が含まれます。値は RGB・CMYK・RGBA・CMYKA の順(画像タイプに依存)です。

@features = $image->Features(1);

Flatten() メソッドは画像のセットを平坦化して返します。たとえば、

$p = $images->Flatten(background=>'none');
$p->Write('flatten.png');

画像シーケンスは、最初の画像の上に 2 番目以降の各画像を重ねて作成された単一の画像で置き換えられます。

Fx() メソッドは画像のセットに数式を適用して結果を返します。たとえば、

$p = $image->Fx(expression=>'(g+b)/2.0',channel=>'red');
$p->Write('fx.miff');

は赤チャンネルを緑と青チャンネルの平均で置き換えます。

このメソッドの詳細な議論は FX、特殊効果画像演算子 を参照してください。

Histogram() は画像内の一意な色とそれぞれの個数を返します。返される値は、赤・緑・青・不透明度・個数の値の配列です。

Morph() メソッドは画像のセットをモーフィングします。画像の画素とサイズの両方が線形補間され、ある画像から次の画像へのメタモルフォーゼの外観を与えます。

$p = $image->Morph(frames=>_integer_);

ここで frames は生成する中間画像の数です。デフォルトは 1 です。

Mosaic() は画像シーケンスからモザイクを作成します。

Mogrify() メソッドは画像操作メソッド(画像の操作)への単一のエントリポイントです。パラメータはメソッド名と、そのメソッドが必要とするパラメータです。たとえば、次の呼び出しは等価です。

$image->Crop('340x256+0+0');
$image->Mogrify('crop', '340x256+0+0');

MogrifyRegion() メソッドは画像の領域に変換を適用します。Mogrify() に似ていますが、領域ジオメトリで始まります。たとえば、位置 (40, 50) の 100x100 領域を明るくしたいとします。

$image->MogrifyRegion('100x100+40+50', 'modulate', brightness=>50);

PerceptualHash() は視覚的に同一の画像を同一または類似のハッシュへマッピングします。画像検索・認証・索引付け・コピー検出やデジタル透かしに役立ちます。各チャンネルと sRGB・HCLp カラースペースについて 7 つのハッシュ値が返されます。たとえば sRGB 画像では 42 個の知覚ハッシュが期待されます。

@phash = $image->PerceptualHash();

Ping() は、画像をメモリへ読み込まずに画像に関する情報を返す便利なメソッドです。画像の幅・高さ・バイト単位のファイルサイズ・ファイル形式を返します。複数のファイル名を指定できますが、ファイルハンドルは 1 つだけです。

($width, $height, $size, $format) = $image->Ping('logo.png');
($width, $height, $size, $format) = $image->Ping(file=>\*IMAGE);
($width, $height, $size, $format) = $image->Ping(blob=>$blob);

これは、画像が存在するか、その特性が何かを問い合わせる、より効率的でメモリ消費の少ない方法です。

Poly() は画像シーケンスと対応する項(係数と次数のペア)から多項式を構築します。

$p = $image->Poly([0.5,1.0,0.25,2.0,1.0,1.0]);

PreviewImage() は、画像処理操作をさまざまな強度で適用した指定画像のサムネイル 9 個をタイル状に並べます。特定の画像処理操作に適したパラメータを特定するのに役立ちます。次の操作から選びます: Rotate, Shear, Roll, Hue, Saturation, Brightness, Gamma, Spiff, Dull, Grayscale, Quantize, Despeckle, ReduceNoise, AddNoise, Sharpen, Blur, Threshold, EdgeDetect, Spread, Solarize, Shade, Raise, Segment, Swirl, Implode, Wave, OilPaint, CharcoalDrawing, JPEG。例を示します。

$preview = $image->Preview('Gamma');
$preview->Display();

テキスト配置を完全に制御するにはフォントメトリクス情報が必要です。次を使います。

($x_ppem, $y_ppem, $ascender, $descender, $width, $height, $max_advance) =
  $image->QueryFontMetrics(_parameters_);

ここで parameters は Annotate メソッドの任意のパラメータです。返される値は次のとおりです。

1. 文字幅
2. 文字高さ
3. アセンダー
4. ディセンダー
5. テキスト幅
6. テキスト高さ
7. 最大水平アドバンス
8. 境界: x1
9. 境界: y1
10. 境界: x2
11. 境界: y2
12. 原点: x
13. 原点: y

複数行テキストの最大テキスト幅・高さを得るには QueryMultilineFontMetrics() を使います。

既知の色名の一覧を返すには QueryColor() をパラメータなしで呼び、1 つ以上の色名を指定すると赤・緑・青・不透明度の値を取得します。

@colors = $image->QueryColor();
($red, $green, $blue) = $image->QueryColor('cyan');
($red, $green, $blue, $alpha) = $image->QueryColor('#716baeff');

QueryColorname() は色値を受け取り、それぞれの名前または 16 進値を返します。

$name = $image->QueryColorname('rgba(80,60,0,0)');

既知のフォントの一覧を返すには QueryFont() をパラメータなしで呼び、1 つ以上のフォント名を指定すると、フォント名・説明・ファミリ・スタイル・ストレッチ・ウェイト・エンコーディング・ファウンドリ・フォーマット・メトリクス・グリフの値を取得します。

@fonts = $image->QueryFont();
$weight = ($image->QueryFont('Helvetica'))[5];

既知の画像形式の一覧を返すには QueryFormat() をパラメータなしで呼び、1 つ以上の形式名を指定すると、adjoin・blob サポート・raw・デコーダー・エンコーダー・説明・モジュールの属性を取得します。

@formats = $image->QueryFormat();
($adjoin, $blob_support, $raw, $decoder, $encoder, $description, $module) =
  $image->QueryFormat('gif');

画像形式名で MagickToMime() を呼ぶと、tif から image/tiff のような MIME タイプを取得します。

$mime = $image->MagickToMime('tif');

すでに実行中の display または animate アプリケーションへコマンドを送るには RemoteCommand() を使います。唯一のパラメータは表示またはアニメーションする画像ファイルの名前です。

$image->RemoteCommand('image.jpg');

Smush() メソッドは画像のセットを密着させて連結します。たとえば、

$p = $image->Smush(stack=>{true,false},offset=>integer);

はオブジェクト $image に関連付けられたすべての画像を密着連結します。デフォルトでは左から右へ密着させます。上から下へ密着させるには stack を True にします。

Statistics() は画像内の各チャンネルの画像統計を返します。返される値は、深度・最小値・最大値・平均・標準偏差・尖度・歪度・エントロピーの値の配列で、RGB・CMYK・RGBA・CMYKA の順(画像タイプに依存)です。

@statistics = $image->Statistics();

最後に、Transform() メソッドは、1 つ以上の画像の切り抜きまたはリサイズのための完全修飾ジオメトリ指定を受け取ります。たとえば、

$p = $image->Transform(crop=>'100x100+0+0');

上記の任意のメソッド名に Image を追加できます。たとえば PingImage() は Ping() メソッドの別名です。

例外処理

すべての PerlMagick メソッドは成功時に未定義の文字列コンテキストを返します。問題が起きると、エラーは数値ステータスコードを埋め込んだ文字列として返されます。400 未満のステータスコードは警告です。これは操作が完了しなかったがある程度回復可能だったことを意味します。400 以上の数値コードはエラーで、操作が完全に失敗したことを示します。各メソッドで例外がどう返されるかを示します。

数値を返すメソッド(Read()・Write() など):

$x = $image->Read(...);
warn "$x" if "$x";      # エラーメッセージを出力
$x =~ /(\d+)/;
print $1;               # エラー番号を出力
print 0+$x;             # 読み込んだ画像数を出力

画像に対して操作するメソッド(Resize()・Crop() など):

$x = $image->Crop(...);
warn "$x" if "$x";      # エラーメッセージを出力
$x =~ /(\d+)/;
print $1;               # エラー番号を出力

画像を返すメソッド(EvaluateSequence()・Montage()・Clone())は次のようにエラーをチェックすべきです。

$x = $image->Montage(...);
warn "$x" if !ref($x);  # エラーメッセージを出力
$x =~ /(\d+)/;
print $1;               # エラー番号を出力

エラーメッセージの例を示します。

Error 400: Memory allocation failed

エラーと警告コード の完全な一覧を確認してください。

次は数値ステータスコードの使い方を示します。

$x = $image->Read('rose.png');
$x =~ /(\d+)/;
die "unable to continue" if ($1 == ResourceLimitError);

定数

PerlMagick には以下の定数が含まれます。

BlobError
BlobWarning
CacheError
CacheWarning
CoderError
CoderWarning
ConfigureError
ConfigureWarning
CorruptImageError
CorruptImageWarning
DelegateError
DelegateWarning
DrawError
DrawWarning
ErrorException
FatalErrorException
FileOpenError
FileOpenWarning
ImageError
ImageWarning
MissingDelegateError
MissingDelegateWarning
ModuleError
ModuleWarning
Opaque
OptionError
OptionWarning
QuantumDepth
QuantumRange
RegistryError
RegistryWarning
ResourceLimitError
ResourceLimitWarning
StreamError
StreamWarning
Success
Transparent
TypeError
TypeWarning
WarningException
XServerError
XServerWarning

次のようにアクセスできます。

Image::Magick->QuantumDepth